home *** CD-ROM | disk | FTP | other *** search
/ The Atari Compendium / The Atari Compendium (Toad Computers) (1994).iso / files / prgtools / programm.ing / falcon / nt_dsp1.lzh / NT_DSP1.MSA / FFT / FFTR2CN.ASM < prev    next >
Encoding:
Assembly Source File  |  1990-01-17  |  6.6 KB  |  166 lines
  1. ;
  2. ; This program originally available on the Motorola DSP bulletin board.
  3. ; It is provided under a DISCLAMER OF WARRANTY available from
  4. ; Motorola DSP Operation, 6501 Wm. Cannon Drive W., Austin, Tx., 78735.
  5. ; 
  6. ; Radix 2, In-Place, Decimation-In-Time FFT (fast).
  7. ; 
  8. ; Last Update 18 Aug 88   Version 1.0
  9. ;
  10. fftr2cn  macro   points,data,odata,coef
  11. fftr2cn  ident   1,0
  12. ;
  13. ; Radix 2 Decimation in Time In-Place Fast Fourier Transform Routine
  14. ;
  15. ;    Complex input and output data
  16. ;        Real data in X memory
  17. ;        Imaginary data in Y memory
  18. ;    Normally ordered input data
  19. ;    Normally ordered output data
  20. ;       Coefficient lookup table
  21. ;        -Cosine values in X memory
  22. ;        -Sine values in Y memory
  23. ;
  24. ; Macro Call - fftr2cn   points,data,odata,coef
  25. ;
  26. ;       points     number of points (16-32768, power of 2)
  27. ;       data       start of data buffer
  28. ;       odata      start of output data buffer
  29. ;       coef       start of sine/cosine table
  30. ;
  31. ; Alters Data ALU Registers
  32. ;       x1      x0      y1      y0
  33. ;       a2      a1      a0      a
  34. ;       b2      b1      b0      b
  35. ;
  36. ; Alters Address Registers
  37. ;       r0      n0      m0
  38. ;       r1      n1      m1
  39. ;               n2
  40. ;
  41. ;       r4      n4      m4
  42. ;       r5      n5      m5
  43. ;       r6      n6      m6
  44. ;
  45. ; Alters Program Control Registers
  46. ;       pc      sr
  47. ;
  48. ; Uses 6 locations on System Stack
  49. ;
  50. ; Latest Revision - 18 Aug-88
  51. ;
  52.      move #data,r0            ;initialize input pointer
  53.      move #points/4,n0        ;initialize input and output pointers offset
  54.      move n0,n4               ;
  55.      move n0,n6               ;initialize coefficient offset
  56.      move #points-1,m0        ;initialize address modifiers
  57.      move m0,m1               ;for modulo addressing
  58.      move m0,m4
  59.      move m0,m5
  60. ;
  61. ; Do first and second Radix 2 FFT passes, combined as 4-point butterflies
  62. ;
  63.      move           x:(r0)+n0,x0
  64.      tfr  x0,a      x:(r0)+n0,y1   
  65.  
  66.      do   n0,_twopass
  67.      tfr  y1,b      x:(r0)+n0,y0
  68.      add  y0,a      x:(r0),x1                     ;ar+cr
  69.      add  x1,b      r0,r4                         ;br+dr
  70.      add  a,b       (r0)+n0                       ;ar'=(ar+cr)+(br+dr)
  71.      subl b,a       b,x:(r0)+n0                   ;br'=(ar+cr)-(br+dr)
  72.      tfr  x0,a      a,x0           y:(r0),b
  73.      sub  y0,a                     y:(r4)+n4,y0   ;ar-cr
  74.      sub  y0,b      x0,x:(r0)                     ;bi-di
  75.      add  a,b                      y:(r0)+n0,x0   ;cr'=(ar-cr)+(bi-di)
  76.      subl b,a       b,x:(r0)                      ;dr'=(ar-cr)-(bi-di)
  77.      tfr  x0,a      a,x0           y:(r4),b
  78.      add  y0,a                     y:(r0)+n0,y0   ;bi+di
  79.      add  y0,b      x0,x:(r0)+n0                  ;ai+ci
  80.      add  b,a                      y:(r0)+,x0     ;ai'=(ai+ci)+(bi+di)
  81.      subl a,b                      a,y:(r4)+n4    ;bi'=(ai+ci)-(bi+di)
  82.      tfr  x0,a                     b,y:(r4)+n4
  83.      sub  y0,a      x1,b                          ;ai-ci
  84.      sub  y1,b      x:(r0)+n0,x0                  ;dr-br
  85.      add  a,b       x:(r0)+n0,y1                  ;ci'=(ai-ci)+(dr-br)
  86.      subl b,a                      b,y:(r4)+n4    ;di'=(ai-ci)-(dr-br)
  87.      tfr  x0,a                     a,y:(r4)+
  88. _twopass
  89. ;
  90. ; Perform all next FFT passes except last pass with triple nested DO loop
  91. ;    
  92.      move #points/8,n1        ;initialize butterflies per group
  93.      move #4,n2               ;initialize groups per pass
  94.      move #-1,m2              ;linear addressing for r2
  95.      move #0,m6               ;initialize C address modifier for
  96.                               ;reverse carry (bit-reversed) addressing
  97.  
  98.      do   #@cvi(@log(points)/@log(2)-2.5),_end_pass    ;example: 7 passes for 1024 pt. FFT
  99.      move #data,r0                                     ;initialize A input pointer
  100.      move r0,r1
  101.      move n1,r2
  102.      move r0,r4                                        ;initialize A output pointer
  103.      move (r1)+n1                                      ;initialize B input pointer
  104.      move r1,r5                                        ;initialize B output pointer
  105.      move #coef,r6                                     ;initialize C input pointer
  106.      lua  (r2)+,n0                                     ;initialize pointer offsets
  107.      move n0,n4
  108.      move n0,n5
  109.      move (r2)-                                        ;butterfly loop count
  110.      move           x:(r1),x1      y:(r6),y0           ;lookup -sine and -cosine values
  111.      move           x:(r6)+n6,x0   y:(r0),b            ;update C pointer, preload data
  112.      mac  x1,y0,b                  y:(r1)+,y1
  113.      macr -x0,y1,b                 y:(r0),a
  114.  
  115.      do   n2,_end_grp
  116.      do   r2,_end_bfy
  117.      subl b,a       x:(r0),b       b,y:(r4)            ;Radix 2 DIT butterfly kernel
  118.      mac  -x1,x0,b  x:(r0)+,a      a,y:(r5)
  119.      macr -y1,y0,b  x:(r1),x1
  120.      subl b,a       b,x:(r4)+      y:(r0),b
  121.      mac  x1,y0,b                  y:(r1)+,y1
  122.      macr -x0,y1,b  a,x:(r5)+      y:(r0),a
  123. _end_bfy
  124.      move (r1)+n1
  125.      subl b,a       x:(r0),b       b,y:(r4)
  126.      mac  -x1,x0,b  x:(r0)+n0,a    a,y:(r5)
  127.      macr -y1,y0,b  x:(r1),x1      y:(r6),y0
  128.      subl b,a       b,x:(r4)+n4    y:(r0),b
  129.      mac  x1,y0,b   x:(r6)+n6,x0   y:(r1)+,y1
  130.      macr -x0,y1,b  a,x:(r5)+n5    y:(r0),a
  131. _end_grp
  132.      move n1,b1
  133.      lsr  b    n2,a1     ;divide butterflies per group by two
  134.      lsl  a    b1,n1     ;multiply groups per pass by two
  135.      move a1,n2
  136. _end_pass
  137. ;
  138. ; Do last FFT pass
  139. ;
  140.      move #2,n0          ;initialize pointer offsets
  141.      move n0,n1
  142.      move #points/4,n4   ;output pointer A offset
  143.      move n4,n5          ;output pointer B offset
  144.      move #data,r0       ;initialize A input pointer
  145.      move #odata,r4      ;initialize A output pointer
  146.      move r4,r2          ;save A output pointer
  147.      lua  (r0)+,r1       ;initialize B input pointer
  148.      lua  (r2)+n2,r5     ;initialize B output pointer
  149.      move #0,m4          ;bit-reversed addressing for output ptr. A
  150.      move m4,m5          ;bit-reversed addressing for output ptr. B
  151.      move #coef,r6       ;initialize C input pointer
  152.      move (r5)-n5        ;predecrement output pointer
  153.      move           x:(r1),x1      y:(r6),y0
  154.      move           x:(r5),a       y:(r0),b
  155.  
  156.      do   n2,_lastpass
  157.      mac  x1,y0,b   x:(r6)+n6,x0   y:(r1)+n1,y1   ;Radix 2 DIT butterfly kernel
  158.      macr -x0,y1,b  a,x:(r5)+n5    y:(r0),a       ;with one butterfly per group
  159.      subl b,a       x:(r0),b       b,y:(r4)
  160.      mac  -x1,x0,b  x:(r0)+n0,a    a,y:(r5)
  161.      macr -y1,y0,b  x:(r1),x1      y:(r6),y0
  162.      subl b,a       b,x:(r4)+n4    y:(r0),b
  163. _lastpass
  164.      move           a,x:(r5)+n5
  165.      endm
  166. ^Z